//dimensions are in cm
//+x points beam-right (towards ndet)
//+y points to hall ceiling
//+z points downstream

#include "colors.inc"
#include "metals.inc"

//#declare Insert = 1;
#declare General = 1;

//following are declarations of some target objects
//each should have its geometric center on the origin

#declare he_shield =
  difference {
    union {
      box {< 3.850,-15.000,-3.850>, <-3.850, 5.000,-3.774>}
      box {< 3.850,-15.000,-3.850>, < 3.774, 5.000, 3.850>}
      box {< 3.850,-15.000, 3.850>, <-3.850, 5.000, 3.774>}
      box {<-3.850,-15.000, 3.850>, <-3.774, 5.000,-3.850>}
      text{ttf "timrom.ttf" "upstream" .1, 0
	   rotate y*180
           translate <2,4.3,-3.85>
	   pigment{Blue}
          }
    }
    union {
      cylinder {< 0.000, 0.000,-4.000>, < 0.000, 0.000,-3.000>, 1.750}
      cylinder {< 0.000, 0.000, 3.000>, < 0.000, 0.000, 4.000>, 2.250}
    }
  }

#declare cup =
  cylinder {
    < 0.000, 0.000,-1.500>,
    < 0.000, 0.000, 1.500>,
    1.270
    open
  }

#declare carbon_target =
  union {
    object {cup pigment{Yellow}}
    cylinder {< 0.000,0.000,-0.357>, < 0.000, 0.000, 0.332>, 1.269
              pigment{Gray50}
    }
  }

#declare ladder =
  difference {
    union {
      box {< 1.509, 8.476,-1.238>, <-1.509, 8.044,-0.890>} //support at top
      box {< 1.509, 8.476,-1.556>, <-1.509,-8.476,-1.238>} //body of ladder
      box {< 1.509,-8.476,-1.556>, <-1.509,-8.222, 1.556>} //foot
    }
    union {
      box {< 1.204, 3.434,-1.556>, < 1.509, 3.892,-1.238>} //notch
      cylinder {< 0.000,-6.416,-2.000>, < 0.000,-6.416,-1.000>, 1.394} //empty
      cylinder {< 0.000,-3.282,-2.000>, < 0.000,-3.282,-1.000>, 1.394} //carbon
      cylinder {< 0.000,-0.147,-2.000>, < 0.000,-0.147,-1.000>, 1.394} //bottom
      cylinder {< 0.000, 2.677,-2.000>, < 0.000, 2.677,-1.000>, 0.396} //n/a
      cylinder {< 0.000, 3.663,-2.000>, < 0.000, 3.663,-1.000>, 0.505} //hole
      cylinder {< 0.000, 5.725,-2.000>, < 0.000, 5.725,-1.000>, 1.394} //top
    }
  }

#declare insert =
  union {
    object {ladder translate y*-5.725 pigment{Grey}}
    object {cup translate y*  0.000 pigment{Yellow}}
    object {cup translate y* -5.872 pigment{Yellow}}
    object {carbon_target translate y* -9.007}
    object {cup translate y*-12.141 pigment{Yellow}}
  }

#declare beam =
  cylinder {<0,0,-100>,<0,0,100>,.05}

#declare raster =
  cylinder {<0,0,-100>,<0,0,100>,1.0}

////////////////////////////////////////////////////////////////////////
//insert glamor shot
////////////////////////////////////////////////////////////////////////
#ifdef(Insert)

camera {
  location <10,5,-18>
  up       <0,1,0>
  right    <-1.33,0,0>   //this defines a right-handed system
  look_at  <0, 0, 0>
}

light_source { < 5, 10,-10> color White shadowless}
light_source { < 5, 10,10> color White shadowless}

object {insert translate y*5}

#end

////////////////////////////////////////////////////////////////////////
//
////////////////////////////////////////////////////////////////////////
#ifdef(General)

camera {
  location <-10,22,-15>
  up       <0,1,0>
  right    <-1.33,0,0>   //this defines a right-handed system
  look_at  <0, 0, 0>
}

light_source { < 0, 20,-10> color White shadowless}
light_source { <-1, 4,-10> color White shadowless}
light_source { < 0, 20,10> color White shadowless}

object {beam   pigment{Green filter .7}}
object {raster pigment{Green filter .9}}
object {he_shield   rotate y*-209.637 translate z*0.012 pigment{Red filter .7}}
object {insert translate 12.141*y translate -0.400*z}

#end